PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=gss-git
pkgver=1.0.4.r1.gb20ac80
pkgrel=1
pkgdesc="GNU Generic Security Service"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/gss/"
license=('GPL')
depends=('glibc')
makedepends=('git' 'gengetopt' 'help2man')
provides=("gss=$pkgver")
conflicts=('gss')
options=('staticlibs')
source=("git+https://git.savannah.gnu.org/git/gss.git")
sha256sums=('SKIP')


prepare() {
  cd "gss"

  git submodule update --init --recursive
}

pkgver() {
  cd "gss"

  _tag=$(git tag -l --sort -v:refname | sed '/rc[0-9]*/d' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "gss"

  ./autogen.sh
  ./configure \
    --prefix="/usr" \
    --sysconfdir="/etc"
  make
}

check() {
  cd "gss"

  make check
}

package() {
  cd "gss"

  make DESTDIR="$pkgdir" install
}