PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Phillip Smith <pkgbuild@phs.id.au>
# http://github.com/fukawi2/aur-packages
pkgname=husk
pkgver=0.9.13
pkgrel=1
pkgdesc="An iptables front-end to allow rules to be expressed in a more flexible, free-form style using language."
arch=('any')
url="https://huskfw.info/"
license=('GPL')
depends=('coreutils' 'iptables' 'perl' 'perl-config-inifiles' 'perl-config-simple')
makedepends=('make')
conflicts=('husk-git')
backup=('etc/husk/addr_groups.conf'
        'etc/husk/husk.conf'
        'etc/husk/interfaces.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/fukawi2/$pkgname/archive/v$pkgver.tar.gz")
md5sums=('0219ea53c0c95318d6b2c58b21fc0692')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i Makefile \
      -e 's|/usr/local/|/usr/|g' \
      -e 's|/usr/sbin|/usr/bin|g' \
      -e 's|pod2man|/usr/bin/core_perl/pod2man|g' \
      -e 's|pod2html|/usr/bin/core_perl/pod2html|g'
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR=$pkgdir install
}

# vim:set ts=2 sw=2 et: