PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: a821
# Contributor: DanManN <dnahimov@gmail.com>
# Contributor: jyantis <yantis@yantis.net>
pkgname=python-msgpack-numpy-git
pkgver=0.4.8.r2.g20c5e5b
_gitname=msgpack-numpy
pkgrel=1
pkgdesc="Serialize numpy arrays using msgpack"
arch=('any')
url='https://github.com/lebedov/msgpack-numpy'
license=('BSD-3-Clause')
depends=('python-numpy'
         'python-msgpack')
source=('git+https://github.com/lebedov/msgpack-numpy.git')
sha256sums=('SKIP')
makedepends=('git' 'python-setuptools' 'python-build' 'python-installer' 'python-wheel')
provides=('python-msgpack-numpy')
conflicts=('python-msgpack-numpy')

pkgver() {
  cd ${_gitname}
  git describe --tags --long | sed 's/-/.r/;s/-/./'
}

check() {
  cd ${_gitname}
  python -m unittest -v
}

build() {
  cd ${_gitname}
  python -m build --wheel --no-isolation
}

package() {
  cd ${_gitname}
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -D -m644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}