blob: 6e6c427cf6676f17b92aaa9e79a34d06aebe546c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Volker Schwaberow <volker@schwaberow.de>
pkgname=rprobe
pkgver=0.5.6
pkgrel=1
pkgdesc="A tool in Rust that can check which HTTP or HTTPS hosts are online"
arch=('x86_64')
url="https://github.com/vschwaberow/rprobe"
license=('MIT' 'Apache')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('e1cfeea1860346d53f20f278c8047867843294ab23d2170d80e91fba8f16f17d')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen
}
check() {
cd "$pkgname-$pkgver"
cargo test --frozen
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/rprobe" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm 644 LICENSE-APACHE -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim:set ts=2 sw=2 et:
|