PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer : envolution
# Contributor: mnussbaum
# Contributor: j.r <j.r@jugendhacker.de>

pkgname=stygiansift-git
_pkgname="StygianSift"
pkgver=r137+g95506d465
pkgrel=2
pkgdesc="A highly customizable TUI file explorer"
arch=("x86_64")
url="https://github.com/Mauitron/StygianSift"
license=("Custom")
depends=(ttf-jetbrains-mono-nerd)
makedepends=("git" "rust" "cargo")
provides=("stygiansift")
conflicts=("stygiansift")
source=("$_pkgname::git+https://github.com/Mauitron/StygianSift.git")
sha256sums=('SKIP')

pkgver(){
  cd "${srcdir}/${_pkgname}"
  _commits=$(git rev-list --count HEAD)
  _short_commit_hash=$(git rev-parse --short=9 HEAD)
  echo "r${_commits}+g${_short_commit_hash}"
}

prepare() {
  cd "$_pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "$_pkgname"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release --all-features
}

package() {
  install -Dm755 "$srcdir/$_pkgname/target/release/StygianSift" "$pkgdir/usr/bin/stygiansift"
  install -Dm644 "$srcdir/$_pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}

# vim: ts=2 sw=2 et: