blob: 06927ae2f07b7fb0deca451971ffd38306e1c497 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Ruben Agin <phabrics@phabrics.com>
_gtk="${GTKMAJ:-gtk4}"
pkgname=tme-git
pkgver=0.12rc11.r33.g25942ed
pkgrel=1
pkgdesc="The Machine Emulator, or tme, provides a general-purpose framework for computer emulation."
arch=('i686' 'x86_64')
license=('GPL3')
url="http://phabrics.com"
optdepends=('perl-x11-protocol: for computing optimal graphics parameters'
'libvncserver: graphics hosted via VNC server'
"${_gtk}: graphics hosted via ${_gtk}"
'sdl2: graphics hosted via SDL2')
makedepends=('git' 'perl-x11-protocol' 'libvncserver' "${_gtk}" 'sdl2')
provides=('tme')
conflicts=('tme')
source=("tme::git+https://github.com/phabrics/nme.git")
sha256sums=('SKIP')
options=(libtool debug !strip lto)
install=$pkgname.install
pkgver() {
cd "$srcdir/tme"
( set -o pipefail
git describe --long --abbrev=7 --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
)
}
build()
{
cd "$srcdir/tme"
autoreconf -fi
./configure --prefix=/usr --disable-ltdl-install --enable-debug
make
}
package()
{
cd "$srcdir/tme"
make DESTDIR="$pkgdir/" install
}
|