Arch Linux User Repository

Any ideas on what to do with the fact upstream is unmaintained? I'm wondering if I should provide a version of the PKGBUILD that builds the seblucas fork in a separate package, that is if you don't want to change this package over. I'd also like to offer to co-maintain this package if you'd like to shift it over to the fork and you are interested in a co-maintainer.

There is a maintained and up to date fork: https://github.com/mikespub-org/seblucas-cops, something like this seems to work fine:

pkgname=cops-seblucas
_name="cops"
_github_name="seblucas-cops"
provides=('cops')
conflicts=('cops')
pkgver=2.6.1
pkgrel=1
pkgdesc='Lightweight Calibre OPDS (and HTML) PHP Server'
arch=('any')
url="https://github.com/mikespub-org/$_github_name"
license=('GPL-2.0-or-later')
depends=(
  'php'
  'php-gd'
  'php-intl'
  'php-sqlite'
)
optdepends=(
  'apache: Web server to run COPS'
  'nginx: Web server to run COPS'
  'cherokee: Web server to run COPS'
)
makedepends=('composer')
backup=("etc/webapps/${_name}/config_local.php")
install="${_name}.install"
source=("${url}/archive/${pkgver}.tar.gz")
sha256sums=('44f1befbf8a7e301920c35aa31cc02d849b9b6bd29fc9e7cf5f7ad8e8f366306')

prepare () {
    cd "${_github_name}-$pkgver"
    # The external packages are requirements, and they cause composer errors if
    # building in chroot
    composer update --no-dev \
    --ignore-platform-req=ext-gd \
    --ignore-platform-req=ext-intl \
    --ignore-platform-req=ext-pdo_sqlite \
    --ignore-platform-req=ext-iconv
}

build () {
    cd "${_github_name}-$pkgver"
    composer install --no-dev --optimize-autoloader \
    --ignore-platform-req=ext-gd \
    --ignore-platform-req=ext-intl \
    --ignore-platform-req=ext-pdo_sqlite \
    --ignore-platform-req=ext-iconv
}

package () {
    cd "${_github_name}-$pkgver"
    install -Dm0644 config_local.php.example "$pkgdir/etc/webapps/cops/config_local.php"
    install -d "$pkgdir/usr/share/webapps"
    cp -r ./ "$pkgdir/usr/share/webapps/${_name}"
    rm -R "${pkgdir}/usr/share/webapps/${_name}/test"
    rm -R "${pkgdir}/usr/share/webapps/${_name}/tools"
    ln -s "/etc/webapps/${_name}/config_local.php" "$pkgdir/usr/share/webapps/${_name}/"
    ln -s "/etc/webapps/${_name}/metadata.db" "$pkgdir/usr/share/webapps/${_name}/"
}

Broken (PKGBUILD fails).

Upstream not maintained since 2019; EOL since last year.

I ran out of free time to sort out the kinks on this package. Feel free to take over.