Arch Linux User Repository

I understand your thought. But I think this is a wrong assumption. Git packages are existing and used exactly for that purpose. People first install the normal version. And only in case of problems, or when they want to use a certain commit right now (before a release happens), they install git version. And of course they are aware of potential problems as that is not considered as released. You do not need to maintain it much. If the build process is not changed, it will be considered as updated even in case of new commits presented in upstream. See https://wiki.archlinux.org/title/AUR_submission_guidelines#Publishing_new_package_content Edit: Ok, I will maintain it myself. Bug thanks for your utility!

@Ashark: As the developer of evsieve, my policy is that the in-development version is not recommended for general use; in particular, I am not trying to keep the main branch backwards compatible. If some user were to use the git version, then they may find at some later point that a feature they relied on has been changed and now their script no longer works.

As such the README only documents the features of the stable version, provides build instruction for the stable version, and I only provide an AUR package for the stable version.

I suppose that building from the main branch is fine for the advanced user who opens Github issues to keep their scripts working, but the more casual user probably wants to just write a script once and then forget about it, and would not be amused if it were to break later because I just happened to whimsically change my mind.

Releasing an evsieve-git AUR package feels like implicitly endorsing the use of the git version as well, which is why I haven't made one so far.

Hi! Wouldn't you like to add evsieve-git package to aur? You can take this for it:

# Maintainer: Kars Mulder <devmail@karsmulder.nl>
pkgname=evsieve-git
_pkgname=${pkgname%-git}
pkgver=v1.3.1.r145.g1a2b24e
pkgrel=1
pkgdesc="A utility for mapping events from Linux event devices."
arch=("x86_64")
url="https://github.com/KarsMulder/${_pkgname}"
license=("GPL2" "MIT")
depends=("libevdev" "gcc-libs")
makedepends=("git" "rust")
provides=(${_pkgname})
conflicts=(${_pkgname})
source=("git+${url}")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "${_pkgname}"
    cargo fetch --locked --target x86_64-unknown-linux-gnu
}

build() {
    cd "${_pkgname}"
    cargo build --release --frozen --target-dir=target
}

package() {
    cd "${_pkgname}"

    install -Dm 755 "target/release/${_pkgname}" -t "${pkgdir}/usr/bin"
    _pkg_license_dir="${pkgdir}/usr/share/licenses/${_pkgname}"
    install -Dm 644 "COPYING" -t "$_pkg_license_dir"
    install -Dm 644 "LICENSE" -t "$_pkg_license_dir"
    cp -R licenses "$_pkg_license_dir"
    find "$_pkg_license_dir" -type f -exec chmod 644 -- {} +
    find "$_pkg_license_dir" -type d -exec chmod 755 -- {} +
} 

@joey_clay: Thank you for the feedback. The new version uses your suggested naming scheme for source.

Please consider changing source to:
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
Very handy for those of us who archive sources in SRCDEST.
https://wiki.archlinux.org/index.php/Pkgbuild#source
Thank you for making evsieve, it's very useful and well-made!