Arch Linux User Repository

tippfehlr: thanks!

heddxh: Chewing_Bever disowned the package for now, leaving me as maintainer. I added you as co-maintainer.

evthestrike: I’ve updated the PKGBUILD, thanks. I’m not sure whether to bump pkgrel for vcs packages, so I didn’t.

fish_files should be added to

cp -r node_modules out package.json "$pkgdir/usr/lib/node_modules/fish-lsp"

such that it would read

cp -r node_modules out package.json fish_files "$pkgdir/usr/lib/node_modules/fish-lsp"

@heddxh I tried to contact Chewing_Bever on Matrix without success, so I sent an orphan request. If they don’t respond and the request is accepted maybe we could co-maintain this package.

@tippfehlr That's great. @Chewing_Bever I am glad to re-maintain this package if you don't want it

That has been fixed in https://github.com/ndonfris/fish-lsp/pull/49

@tippfehlr this lsp will check log file during startup besides the bin path, is this case it is /usr/bin, which definitely has permission issue. Is that happen to you?

Thanks for packaging this! Unfortunately, it doesn’t work. It doesn’t even package anything to run.

I’ve fixed it:

# Maintainer: Heddxh <g311571057 at gmail dot com>
pkgname=fish-lsp-git
_pkgname=${pkgname%-git}
pkgver=r317.782e14a
pkgrel=1
pkgdesc="LSP implementation for the fish shell language"
# tree-sitter contains compiled files
arch=('x86_64')
url="https://github.com/ndonfris/fish-lsp/"
license=('MIT')
depends=('fish' 'nodejs')
makedepends=('git' 'yarn' 'typescript')
provides=($_pkgname)
conflicts=($_pkgname)
source=("$pkgname::git+https://github.com/ndonfris/fish-lsp.git")
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
    cd "$pkgname"
    yarn --frozen-lockfile --ignore-scripts
}

build() {
    cd "$pkgname"
    tsc
    ./bin/fish-lsp complete >./fish-lsp.fish
}

package() {
    cd "$pkgname"
    mkdir -p "$pkgdir/usr/bin"
    mkdir -p "$pkgdir/usr/lib/node_modules/fish-lsp"

    rm -r node_modules/@types
    cp -r node_modules out package.json "$pkgdir/usr/lib/node_modules/fish-lsp"
    # nvim-lspconfig doesn’t work without this symlink
    ln -s /usr/lib/node_modules/fish-lsp/node_modules/@esdmr/tree-sitter-fish/tree-sitter-fish.wasm \
        "$pkgdir/usr/lib/node_modules/fish-lsp/"

    printf "%s\n" "#!/usr/bin/env node" "require('/usr/lib/node_modules/fish-lsp/out/cli');" >"$pkgdir/usr/bin/fish-lsp"
    chmod 755 "$pkgdir/usr/bin/fish-lsp"

    install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 "fish-lsp.fish" "$pkgdir/usr/share/fish/vendor_completions.d/fish-lsp.fish"
}

Have a look at how https://gitlab.archlinux.org/archlinux/packaging/packages/vscode-languageservers/-/blob/main/PKGBUILD?ref_type=heads (an official package) is packaged.

Also @Chewing_Bever, if you are now maintaining this you should add yourself as maintainer and move heddxh to Contributor. And of course generate a .SRCINFO.

If you want you could add me as a co-maintainer.

Thanks!