Arch Linux User Repository

@ecraven, I have made updates to the PKGBUILD to build off the tip.

Changes:
  - Updated source from github.com/vyzo to github.com/mighty-gerbils
  - Removed gambit-c from depends and makedepends as upstreams builds and uses a pinned gambit-c for both build and runtime
  - Added openssl, zlib and sqlite as dependency to build with upstream defaults
  - Added a pkgver() to update PKGBUILD's pkgver tag
  - Updated build() and package() functions to be thin wrappers over upstream installation instructions
  - Removed GERBIL_HOME as upstream have deprecated requiring this env variable.
  - Corrected here-document to not have $PATH expanded during package build

# Maintainer: Peter <craven@gmx.net>
pkgname=gerbil-scheme-git
_pkgname=gerbil
pkgver=0
pkgrel=1
pkgdesc="Gerbil is an opinionated dialect of Scheme designed for Systems Programming, with a state of the art macro and module system on top of the Gambit runtime."
arch=(x86_64 i686)
url="https://cons.io"
source=("git+https://github.com/mighty-gerbils/gerbil.git")
sha1sums=("SKIP")
license=('LGPLv2.1' 'Apache 2.0')
depends=('openssl' 'zlib' 'sqlite')
makedepends=('git')
provides=("gerbil-scheme")
conflicts=("gerbil-scheme")

# Use git describe to derive the version as is done by upstream. See 
# ./configure:60, gerbil_version. pkgver() derived this way will contain
# hyphens. Since pkgver cannot contain hyphens, substitute - with _
pkgver() {
  cd "$_pkgname"
  git describe --tags --always | sed 's/-/_/g'
}

build() {
  cd "$_pkgname"
  ./configure --prefix=/opt/gerbil
  make
}

package() {
  cd "$_pkgname"
  make DESTDIR=${pkgdir} install

  mkdir -p ${pkgdir}/etc/profile.d/
  cat <<'EOF' > ${pkgdir}/etc/profile.d/gerbil-scheme.sh
export PATH=/opt/gerbil/bin:$PATH
EOF
}

# vim:set ts=2 sw=2 et:

Please let me know for any questions. If you are good with the changes, please consider updating the PKGBUILD.

Hello, gambit-c is a runtime dependency and not a make dependency only. It make the package impossible to use unless gambit-c have been installed before.

Your .SRCINFO file is duplicated. You probably used >> instead of > when making it.