Arch Linux User Repository

it looks like the Makefile has changed significantly in the last two months so i had to make some changes to the PKGBUILD:

# Maintainer: éclairevoyant
# Contributor: Caleb Maclennan <caleb at alerque dot com>
# Contributor: DaZ <daz dot root+arch at gmail dot com>

_pkgname=gnvim
pkgname="$_pkgname-git"
pkgver=0.3.1.r87.74efe9b
pkgrel=1
pkgdesc="Opinionated GTK4 Neovim GUI"
arch=(x86_64 aarch64 i686)
url="https://github.com/vhakulinen/$_pkgname"
license=(MIT)
depends=(gtk4 'neovim>=0.10')
makedepends=(cargo git libadwaita)
checkdepends=(xorg-server-xvfb)
provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")
source=("git+$url.git")
b2sums=(SKIP)

prepare() {
    cd $_pkgname
    export RUSTUP_TOOLCHAIN=stable

    sed -i '/@glib-compile-schemas/d' Makefile
    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

pkgver() {
    git -C $_pkgname describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
}

build() {
    cd $_pkgname
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --profile=optimized
}

check() {
    cd $_pkgname
    export RUSTUP_TOOLCHAIN=stable
    xvfb-run cargo test --frozen
}

package() {
    make -C $_pkgname PREFIX="/usr" DESTDIR="$pkgdir" install
}

namely:

• neovim>=0.10 in requirements to match upstream requirements.
• libadwaita added to makedepends.
• sed -i '/@glib-compile-schemas/d' Makefile added to prepare(), replacing the previous sed statement. the old one doesn't appear to be required now. the new one prevents make from compiling the glib schemas as part of the Makefile.
• --release and --all-features removed from cargo build in build(). the Makefile references optimized as the suggested profile, so i swapped to that. --all-features now includes flatpak helpers which aren't required.

Can you add

check() {
    cd "$srcdir/${pkgname}-${pkgver}"
    cargo test
}

?

patched the default path instead, so it works swell without the desktop file as well :^)

The desktop file needs to be modified since gnvim is installed in /usr. The Exec needs to be changed for it to load its own runtime files:

Exec=/usr/bin/gnvim --gnvim-rtp /usr/share/gnvim/runtime -- %F

Thanks!

@trevdev: submitted a couple of patches upstream to fix these issues, if they get merged our problems are solved.

Just a heads up, the .desktop reference is broken on install as well as the icon reference. At least, for me it is.

location: /usr/share/applications/gnvim.desktop

Contents [Desktop Entry] Type=Application Encoding=UTF-8 Name=GNvim Exec=/home/<user redacted>/.cache/yay/gnvim-git/pkg/gnvim-git//usr/bin/gnvim -- %F Icon=gnvim.png Terminal=false

Both the Exec/Icon settings seem incorrect. I fixed this manually with the last version but it broke again after updating.

done, thanks for feedback :^)

Please change line 29 of PKGBUILD to

make PREFIX="/usr" DESTDIR="$pkgdir/" install

to install under /usr instead of /usr/local