Arch Linux User Repository

@pullmoll thanks for the look. I decided against increasing pkgrel, since only package metadata was updated and the output of the "extracted package" itself is still the same (see wiki/manpage). Also, on further inspection it still relies on calling php binary in the PKGBUILD's build together with composer (composer-git should be updated to remove the provides thing btw), I don't see a way to make that fully php-interpreter compatible. If you have an idea, please I'm open for input, until then I think the best way is to go back to the variant without -interpreter.

Hi, I have taken also a look into the PKGBUILD. You have already included php-interpreter, but the php-gd,... packages have also -interpreter counterparts. php-intl is always provided by php-interpreter and can be left out. The dependency composer-git is by the way a different package and not related to composer (php). Unfortunately composer has no -interpreter package, yet.

Here is my current version of the PKGBUILD in case and I'd be happy, if you can extend your's:

# Maintainer: danieltetraquark

pkgname=grocy
pkgver=4.4.2
pkgrel=2
pkgdesc="web-based self-hosted groceries & household management solution for your home"
depends=('php-interpreter' 'php-sqlite-interpreter' 'php-gd-interpreter')
makedepends=('composer' 'yarn' 'git')
license=('MIT')
arch=('any')
url="https://grocy.info/"
source=(
https://github.com/grocy/grocy/archive/v${pkgver}.zip
)
sha512sums=('abcdfa2ea36171f466e4158b70df3fa0f7a2bd92e59060a8fa1cd877de09bd1486e5a21b20aa042037a9bbd97312efe95da88080a0827f26c8f4a318395a5ce4')

backup=('etc/webapps/grocy/config.php')

build() {
    cd grocy-${pkgver}

    # composer need to have php-gd extension enabled, otherwise it will fail for a dependency of grocy.
    # note: you may need to adjust your php open_basedir setting, so that php can run!
    php -n -dextension=gd.so -dextension=intl.so /usr/bin/composer install --no-interaction --no-dev --optimize-autoloader
    php /usr/bin/composer clear-cache

    yarn install --modules-folder public/packages --production
    yarn cache clean
}

package() {
    cd grocy-${pkgver}

    _instdir="$pkgdir"/usr/share/webapps/grocy
    mkdir -p "$_instdir" "$pkgdir"/etc/webapps/grocy "$pkgdir"/var/lib/webapps


    # install license
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    # copy files to install directory
    cp -ra . "$_instdir"/

    mv "$pkgdir"/usr/share/webapps/grocy/data "$pkgdir"/var/lib/webapps/grocy

#    mkdir "$pkgdir"/usr/share/webapps/grocy/data/
    ln -s /var/lib/webapps/grocy "$pkgdir"/usr/share/webapps/grocy/data

    ln -s /etc/webapps/grocy/config.php "$pkgdir"/var/lib/webapps/grocy/config.php

    mv config-dist.php "$pkgdir"/etc/webapps/grocy/config.php

    chown 33 "$pkgdir"/var/lib/webapps/grocy
}

Hi, thank you for maintaining the grocy AUR package. Can you make this package depend on php-interpreter, instead of php, please?

@xanikira I've updated the package to 4.4.1. I tested it that it compiles, but as I'm currently quite busy I couldn't test beyond that right now. If you notice anything broken, leave a comment with whats broken.

-- Daniel

@rany thank you, I think you're right. I've updated it. In theory, chowning a symlink should change the owner of the target, but this would fail if you don't have the package already installed and build in a chroot.

Shouldn't the PKGBUILD chown /var/lib/webapps/grocy not /usr/share/webapps/grocy/data? /usr/share/webapps/grocy/data would only chown the symlink to /var/lib/webapps/grocy which isn't very useful.

I just ran into https://github.com/grocy/grocy/issues/2307 which is a consequence of not clearing the viewcache directory (/var/lib/webapps/grocy/viewcache) after update, see https://github.com/grocy/grocy#how-to-update.

@TheHellSite I took notes while I installed grocy and published a step list here: https://gist.github.com/ambiamber/4a3398504c692bc6f24f9b60875fa401