Arch Linux User Repository

I had issues with corepacker; with this patch it worked.

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix

pkgname=heroic-games-launcher
pkgver=2.16.1
pkgrel=1
pkgdesc="Native GOG, Epic Games and Amazon games launcher for Linux"
arch=(x86_64)
url="https://heroicgameslauncher.com/"
license=(GPL-3.0-only)
_electron=electron31
depends=(which $_electron zlib gcc-libs glibc)
makedepends=(git pnpm npm python desktop-file-utils)
source=("git+https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher.git#tag=v${pkgver}")
sha256sums=('d83a38acf365c6ceb3fb2dacca38b79f7b0f4ccf0929b5c25a260d073297614f')

build() {
  cd HeroicGamesLauncher
  # HOME="${srcdir}/.electron-gyp" pnpm install

  pnpm run download-helper-binaries
  npx electron-vite build
  npx electron-builder --linux --x64 --dir -c.electronDist=/usr/lib/$_electron/ -c.electronVersion=$(cat /usr/lib/$_electron/version)
}

package() {
  cd "HeroicGamesLauncher"
  install -d "${pkgdir}/usr/lib/heroic"
  cp -rf dist/linux-unpacked/resources/app.asar{,.unpacked} "${pkgdir}/usr/lib/heroic/"
  rm -rf "${pkgdir}"/usr/lib/heroic/app.asar.unpacked/build/bin/x64/win32
  rm -rf "${pkgdir}"/usr/lib/heroic/app.asar.unpacked/build/bin/arm64
  install -Dm755 /dev/stdin "${pkgdir}/usr/bin/heroic" <<EOF
#!/usr/bin/bash
exec $_electron /usr/lib/heroic/app.asar "\$@"
EOF

  install -Dm644 flatpak/com.heroicgameslauncher.hgl.png -t "${pkgdir}/usr/share/pixmaps"
  install -Dm644 flatpak/templates/com.heroicgameslauncher.hgl.metainfo.xml.template "${pkgdir}"/usr/share/metainfo/com.heroicgameslauncher.hgl.metainfo.xml

  # fix icon on Gnome dock
  desktop-file-edit --set-key=Exec --set-value="heroic %U" --set-key=StartupWMClass --set-value=heroic flatpak/com.heroicgameslauncher.hgl.desktop
  install -Dm644 flatpak/com.heroicgameslauncher.hgl.desktop -t "${pkgdir}/usr/share/applications"
}

@robindegen this is heroic-games-launcher not heroic-games-launcher-bin

newer electron version are not fully backwards compatible; heroic is currently using electron31, using electron34 introduced this bug: https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher/issues/4357

using the binary package resolves this

@FabioLolix Thank you

@smendez fixed

When I run (as an example):

xdg-open heroic://launch/gog/1482265668

I get this error:

kf.kio.core: "/usr/share/applications/com.heroicgameslauncher.hgl.desktop" contains supported protocols but doesn't use %u or %U in its Exec line! This is inconsistent.

If I edit the file and add %u it works of course, but it seems like the package should do this. This wasn't happening before which indicates that its probably a recently introduced requirement for KDE. Maybe adding %u will break it for other systems, so I am not sure what would be the appropriate fix.

Edit: It looks like the %U was there before and recent changes to the package broke this.

@FabioLolix: Changing the StartupWMClass value to 'heroic' resolves the issue. Remove the sed bit from the package function and do the following in the prepare function:

desktop-file-edit --set-key=Exec --set-value=heroic --set-key=StartupWMClass --set-value=heroic flatpak/com.heroicgameslauncher.hgl.desktop

Latest version 2.15.2-4 needs its .desktop to be fixed for its icon to display properly in gnome dock

Changes in 2.15.2-4 is using default file names for those files, fixed the icon on Cinnamon, I don't have gnome or other DE to test on