Arch Linux User Repository

@carlosal1015 I think that it should be a new package named kahip-parallel. This package should use the modified static lib of KaHIP. I’m testing it now. If it succeeds, I will send it to you to add it to the AUR repository. And this package should be used by dolfinx because according to documentation, dolfinx use static libs and need the modified lib that built for parallel.

I guess that it is better disable support Kahip for dolfinx. Or submmit another kahip-static.

@carlosal1015 According the issue made in the GitHub repository the dolfinx package should use the liblibmodified_kahip_interface.a file to works. In the compile_withcmake.sh, this file is renamed in /parallel/libkahip.a. I'm trying to find a fix.

Looks like is not working as shared library, no?

@carlosal1015 I have tested the given examples in the GitHub repository and I found that some tasks failed. I have compile it with compile_withcmake.sh and everything works fine. Also I found that there is a huge difference in files sizes. So I tested the build output with VERBOSE=1 in build and I found that there is a huge difference in flags. So I have edited the PKGBUILD file to make the package provide the dynamic and static libs and give the same files provided by compile_withcmake.sh.Now it works perfectly and the dolfinx package doesn't need anymore the -lkahip flag and the problem of the test related to dolfinx with KaHIP has been solved. Now there is memory issue in dolfinx package releated to the flags that I'm working to fix it. Here is the full PKGBUILD file:

# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
_base=KaHIP
pkgname=${_base,,}
pkgver=3.17
pkgrel=1
pkgdesc="Karlsruhe HIGH Quality Partitioning"
arch=(x86_64)
url="https://github.com/${_base}/${_base}"
license=(MIT)
depends=(openmp metis openmpi python)
options=(staticlibs)
makedepends=(cmake pybind11)
optdepends=('gurobi: for ILP solver in ilp_improve')
source=(${_base}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('5ef655cfa56c466a75739e071f237a8dc915b98f2d066a547691bdd1f871b9233b4d5433df253e78405be63c64a33a3e02feb1fdc17f87b21604a282204bef3d')

build() {
  cmake \
    -S ${_base}-${pkgver} \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_CXX_STANDARD=11 \
    -DCMAKE_C_COMPILER=gcc \
    -DCMAKE_CXX_COMPILER=g++ \
    -DCMAKE_C_FLAGS:STRING="-O3 -DNDEBUG -fPIC" \
    -DCMAKE_CXX_FLAGS:STRING="-O3 -DNDEBUG -fPIC -fpermissive" \
    -DCMAKE_EXE_LINKER_FLAGS="-Wl,--as-needed -Wl,--no-as-needed" \
    -DCMAKE_VERBOSE_MAKEFILE=OFF \
    -DBUILDPYTHONMODULE=ON \
    -DUSE_TCMALLOC=OFF \
    -DUSE_ILP=OFF \
    -D64BITMODE=OFF \
    -Wno-dev
  cmake --build build --target all
}

package() {
  DESTDIR="${pkgdir}" cmake --build build --target install
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  local _pyversion=$(python -c "import sys; print(f'{sys.version_info.major}{sys.version_info.minor}')")
  install -dm755 "${pkgdir}${site_packages}"
  mv "build/${_base,,}.cpython-${_pyversion}-${CARCH}-linux-gnu.so" "${pkgdir}${site_packages}"
  mv -f ${pkgdir}/usr/lib/libkahip_static.a ${pkgdir}/usr/lib/libkahip.a
  mv -f ${pkgdir}/usr/bin/dspac ${pkgdir}/usr/bin/distributed_edge_partitioning
  mv -f ${pkgdir}/usr/lib/libparhip_interface_static.a ${pkgdir}/usr/lib/libparhip.a
  mkdir ${pkgdir}/usr/lib/parallel
  mv -f ${srcdir}/build/parallel/modified_kahip/liblibmodified_kahip_interface.a ${pkgdir}/usr/lib/parallel/libkahip.a
  mv -f ${srcdir}/${_base}-${pkgver}/misc/pymodule/callkahipfrompython.py "${pkgdir}${site_packages}"/callkahipfrompython.py
  install -Dm 644 ${_base}-${pkgver}/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  find "${pkgdir}" -type d -empty -delete
}

Please update it until I fix the dolfinx problems.

@carlosal1015 the sha512sum doesn't match the downloaded file