Package Details: rocsparse-gfx1010 5.6.1-1

Git Clone URL: https://aur.archlinux.org/rocsparse-gfx1010.git (read-only, click to copy)
Package Base: rocsparse-gfx1010
Description: BLAS for sparse computation on top of ROCm - supports only gfx1010 (Navi 10)
Upstream URL: https://rocsparse.readthedocs.io/en/master/
Licenses: MIT
Conflicts: rocsparse
Provides: rocsparse
Submitter: ulyssesrr
Maintainer: None
Last Packager: ulyssesrr
Votes: 0
Popularity: 0.000000
First Submitted: 2023-08-23 01:04 (UTC)
Last Updated: 2023-09-21 03:25 (UTC)

Required by (2)

Sources (1)

Pinned Comments

ulyssesrr commented on 2023-08-23 22:35 (UTC) (edited on 2023-08-23 22:44 (UTC) by ulyssesrr)

Currently gfx1010 architecture is not built by default in rocSPARSE, this package is needed until upstream and/or the official arch package changes that, see upstream issue: https://github.com/ROCmSoftwarePlatform/rocSPARSE/issues/348

Latest Comments

grdgkjrpdihe commented on 2024-11-07 00:48 (UTC)

update to 6.0.2

# Maintainer: Torsten Keßler <tpkessler at archlinux dot org>
# Contributor: Markus Näther <naetherm@informatik.uni-freiburg.de>
pkgname=rocsparse
pkgver=6.0.2
pkgrel=2
pkgdesc='BLAS for sparse computation on top of ROCm'
arch=('x86_64')
url='https://rocm.docs.amd.com/projects/rocSPARSE/en/latest/index.html'
license=('MIT')
depends=('rocm-core' 'glibc' 'gcc-libs' 'hip' 'rocprim')
makedepends=('cmake' 'rocm-cmake' 'gcc-fortran')
_git='https://github.com/ROCmSoftwarePlatform/rocSPARSE'
source=("$pkgname-$pkgver.tar.gz::$_git/archive/rocm-$pkgver.tar.gz")
sha256sums=('00292eb7efe5719a65960bdbe391ba8e0ce610487eea11397aad6a14b11e12cd')
# Disable default build flags and use release mode as otherwise the linker step
# fails. The symbol offset size reaches the 32 bit integer limits.
options=(!lto !buildflags)
_dirname="$(basename "$_git")-$(basename "${source[0]}" ".tar.gz")"

build() {
  # -fcf-protection is not supported by HIP, see
  # https://rocm.docs.amd.com/en/latest/reference/rocmcc.html#support-status-of-other-clang-options
  local cmake_args=(
    -Wno-dev
    -S "$_dirname"
    -B build
    -D CMAKE_BUILD_TYPE=Release
    -D CMAKE_CXX_COMPILER=/opt/rocm/bin/hipcc
    -D CMAKE_CXX_FLAGS="${CXXFLAGS} -fcf-protection=none"
    -D CMAKE_INSTALL_PREFIX=/opt/rocm
    -D AMDGPU_TARGETS="gfx1010"
  )
  cmake "${cmake_args[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  install -Dm644 "$_dirname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

ulyssesrr commented on 2023-08-23 22:35 (UTC) (edited on 2023-08-23 22:44 (UTC) by ulyssesrr)

Currently gfx1010 architecture is not built by default in rocSPARSE, this package is needed until upstream and/or the official arch package changes that, see upstream issue: https://github.com/ROCmSoftwarePlatform/rocSPARSE/issues/348