Arch Linux User Repository

@lpc123 I have no relationship with TradingView and I don't maintain the official packages either from Snap or Debian, so any issues in the official packages should be reported to TradingView itself and not on the AUR. Likewise, issues related to this same package that I maintain unofficially can be discussed here.

@lpc123 I have no relationship with TradingView and I don't maintain the official packages either from Snap or Debian, so any issues in the official packages should be reported to TradingView itself and not on the AUR. Likewise, issues related to this same package that I maintain unofficially can be discussed here.

I have been very careful to configure snap correctly using the steps in the Arch Wiki, however, TradingView continues to periodically crash my system. I cannot determine the cause.

@oneno It's probably an issue with Electron if it was working correctly before. There is not much I can do other than wait for a new version of TV to be released that depends on a newer supported release of Electron that hopefully fixes this problem.

Both versions 2.9.2-1 and the most recent version 2.9.4-1 have "screen tearing" issues when scrolling the mouse wheel forward to increase the width of the bars on a displayed chart especially the most recent bars on the chart.

This problem is not present on version 2.7.2-1

Have checked all other apps used to confirm there is no screen tearing.

CPU has onboard graphics: ATI Richland [Radeon HD 8470D]

@inetol, oh, great find -- looks great! Thanks for your effort! Also: I think it has to do with the fact that the .deb version has only been out for about a month.

@mforthewin They did have a proper dedicated repository for Debian based distros after all, they only keep the last 3 versions (too much to ask for) but it's better than having always the latest release.

I will update this package rn once I check that everything is working properly.

@inetol, it seems to be possible to download specific versions for Windows and macOS releases, however:

https://tvd-packages.tradingview.com/stable/2.8.0/win32/x64/TradingView.msix https://tvd-packages.tradingview.com/stable/2.8.0/darwin/TradingView.dmg

I have not found it to work for the .deb release, however. It might be possible in the future.

@inetol, yes, that is a good point -- I came to the same conclusion. Sadly, there does not seem to be an API for specific releases.

@mforthewin I can't use the deb release because I don't know if previous versions of TradingView are uploaded in the source, nor can I use a source whose package is constantly iterating.

This would be my suggestion for the .deb package (updated to 2.8.0):

PKGBUILD:

# Maintainer: Ivan Gabaldon <aur[at]inetol.net>
# Contributor: sukanka <su975853527 at gmail.com>

pkgname=tradingview
pkgver=2.8.0
pkgrel=1
pkgdesc='A charting platform for traders and investors'
arch=('x86_64')
url='https://www.tradingview.com/desktop/'
license=('LicenseRef-TradingView')
makedepends=('links')
source=("$pkgname-$pkgver.deb::https://tvd-packages.tradingview.com/ubuntu/stable/latest/jammy/tradingview_amd64.deb")
b2sums=('f967621b5dcb596909e9b298a1748d0a71a9e054d697bfe8cbb2760c748614b3a125d281e4d35f2f5df1dd52e6acfb91e32a67e2e58a8b7b13d9f9779ce52df2')

prepare() {
    bsdtar -xf "$srcdir/data.tar.xz" -C "$srcdir"

    # License
    links -width 80 -dump 'https://www.tradingview.com/policies/' | sed -n '/Terms of Use/,/TradingView may update these Rules at any time/p' > "LICENSE.txt"

    sed -i \
        -e "s|Exec=.*|Exec=/usr/bin/$pkgname %U|" \
        -e "s|Icon=.*|Icon=$pkgname|" \
        "$srcdir/usr/share/applications/$pkgname.desktop"
}

package() {
    depends=('alsa-lib'
             'at-spi2-core'
             'cairo'
             'dbus'
             'expat'
             'gcc-libs'
             'glib2'
             'glibc'
             'gtk3'
             'hicolor-icon-theme'
             'libcups'
             'libdrm'
             'libsecret'
             'libx11'
             'libxcb'
             'libxcomposite'
             'libxdamage'
             'libxext'
             'libxfixes'
             'libxkbcommon'
             'libxrandr'
             'mesa'
             'nspr'
             'nss'
             'pango')

    # Install application directory
    install -d "$pkgdir/opt"
    mv "$srcdir/opt/TradingView" "$pkgdir/opt/$pkgname"

    # Create symlink
    install -d "$pkgdir/usr/bin/"
    ln -s "/opt/$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"

    # Install desktop entry
    install -Dm 644 -t "$pkgdir/usr/share/applications" \
        "$srcdir/usr/share/applications/$pkgname.desktop"

    # Install icon
    install -Dm 644 -t "$pkgdir/usr/share/icons/hicolor/512x512/apps" \
        "$srcdir/usr/share/icons/hicolor/512x512/apps/$pkgname.png"

    # Install license
    install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE.txt"
}

.SRCINFO:

pkgbase = tradingview
    pkgdesc = A charting platform for traders and investors
    pkgver = 2.8.0
    pkgrel = 1
    url = https://www.tradingview.com/desktop/
    arch = x86_64
    license = LicenseRef-TradingView
    makedepends = links
    source = tradingview-2.8.0.deb::https://tvd-packages.tradingview.com/ubuntu/stable/latest/jammy/tradingview_amd64.deb
    b2sums = f967621b5dcb596909e9b298a1748d0a71a9e054d697bfe8cbb2760c748614b3a125d281e4d35f2f5df1dd52e6acfb91e32a67e2e58a8b7b13d9f9779ce52df2

pkgname = tradingview
    depends = alsa-lib
    depends = at-spi2-core
    depends = cairo
    depends = dbus
    depends = expat
    depends = gcc-libs
    depends = glib2
    depends = glibc
    depends = gtk3
    depends = hicolor-icon-theme
    depends = libcups
    depends = libdrm
    depends = libsecret
    depends = libx11
    depends = libxcb
    depends = libxcomposite
    depends = libxdamage
    depends = libxext
    depends = libxfixes
    depends = libxkbcommon
    depends = libxrandr
    depends = mesa
    depends = nspr
    depends = nss
    depends = pango