AUR (en) - we-get-git

Git Clone URL:	https://aur.archlinux.org/we-get-git.git (read-only, click to copy)
Package Base:	we-get-git
Description:	Command-line tool for searching torrents.
Upstream URL:	https://github.com/rachmadaniHaryono/we-get
Keywords:	dht downloading network search sharing torrent
Licenses:	MIT
Submitter:	milkii
Maintainer:	milkii
Last Packager:	milkii
Votes:	2
Popularity:	0.000000
First Submitted:	2019-06-01 00:23 (UTC)
Last Updated:	2019-11-17 23:43 (UTC)

Latest Comments

dreieck commented on 2024-11-28 12:19 (UTC)

Package fails:

==> Starting package()...
python: can't open file '/var/cache/makepkg/build/we-get-git/src/we-get/setup.py': [Errno 2] No such file or directory

Seems you should use python -m build in build() and python -m installer in package() now.

ALSO, you miss a couple of make dependencies!:

git
python-build
python-installer
python-poetry
python-wheel

ALSO, python-requests is missing as dependency.

ALSO, you must install a license file.

ALSO, you need to add we-get to the provides and conflicts arrays.

ALSO, arch needs to be any since it contains no binaries.

Below a re-worked PKGBUILD. Please fix your package.

Regards and thanks for the package!

Fixed PKGBUILD:

# Maintainer:  milkii, milk on freenode, (https://aur.archlinux.org/account/milkii)
# Contributor: dreieck
# Contributor: milkii (https://aur.archlinux.org/account/milkii)
_pkgname=we-get
pkgname=${_pkgname}-git
pkgver=1.1.0.r102.gf74a5f5
pkgrel=1
pkgdesc="Command-line tool for searching torrents."
#epoch=0
arch=('any')
url="https://github.com/rachmadaniHaryono/we-get"
license=('MIT')
groups=()
depends=('python>=3' 'python-prompt_toolkit' 'python-requests' 'python-docopt' 'python-colorama')
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-poetry'
  'python-wheel'
)
optdepends=()
## TODO: Re-activate if `check()` is re-activated.
#checkdepends=(
#  'python-pytest'
#  'python-vcrpy'
#)
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
replaces=()
backup=()
options=()
source=(git+https://github.com/rachmadaniHaryono/we-get.git)
noextract=()
md5sums=('SKIP')

prepare() {
  cd "${srcdir}/${_pkgname}"
  git log > "${srcdir}/git.log"
}

pkgver() {
  cd "$_pkgname"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "${srcdir}/${_pkgname}"
  printf '%s\n' " --> building ..."
  python -m build --wheel --no-isolation
}

## 2024-11-28: `check()` currently disabled, since it fails with `tests/test_doc.py:31: AssertionError` (see https://github.com/rachmadaniHaryono/we-get/issues/55)
#check() #{
#  cd "$_pkgname"
#  python -m pytest
#}

package() {
  cd "${srcdir}/${_pkgname}"
  printf '%s\n' " --> installing ..."
  python -m installer --destdir="$pkgdir" --compile-bytecode=2 dist/*.whl

  _docfiles=(
    "${srcdir}/git.log"
    README.rst
  )
  _licensefiles=(
    LICENSE
  )
  printf '%s\n' " --> installing documentation ..."
  for _docfile in "${_docfiles[@]}"; do
    install -D -v -m644 "${_docfile}" "${pkgdir}/usr/share/doc/${_pkgname}/$(basename "${_docfile}")"
  done
  printf '%s\n' " --> installing license ..."
  for _licensefile in "${_licensefiles[@]}"; do
    install -D -v -m644 "${_licensefile}" "${pkgdir}/usr/share/licenses/${pkgname}/$(basename "${_licensefile}")"
    ln -svr "${pkgdir}/usr/share/licenses/${pkgname}/$(basename "${_licensefile}")" "${pkgdir}/usr/share/doc/${_pkgname}/$(basename "${_licensefile}")"
  done
}

99cents commented on 2021-03-19 16:32 (UTC)

that was indeed the problem - i thought refreshing the db would have done that but apparently not (i'm fairly new to linux)

milkii commented on 2021-03-19 10:43 (UTC)

Loads of 404s might indicate a pacman -Sy hasn't been done recently.

99cents commented on 2021-03-19 06:52 (UTC)

package won't build on Manjaro - i'm not sure reporting this is acceptable here, but i'll give it a shot...

indeed if i try and load any of these URL's in a browser they 404

milkii commented on 2019-07-11 23:04 (UTC)

probably! sorted, thanks :)

melentye commented on 2019-07-09 17:33 (UTC) (edited on 2019-07-09 17:33 (UTC) by melentye)

Hi, thanks for packaging the app! Did you mean to depend on python-docopt instead of just docopt?

Arch Linux User Repository

Search Criteria

Package Details: we-get-git 1.1.0.r13.gaeec72f-1

Package Actions

Dependencies (3)

Required by (0)

Sources (1)