Arch Linux User Repository

WeChat will soon split into 2 packages. While wechat-bin will be the new "vanilla" version, this package will revert back to the original state and automatically set env vars for input method, HiDPI and more. The sandbox will still remain optional in this package, though.

右键应用程序图标可与微信共享文件. 其将被放置在沙盒的 ~/Shared 中.

WeChat_Data/portable.env 中的环境变量将会自动导入至微信.

不支持纯 Wayland 环境, 微信并未构建 Wayland 模块.

若要查看使用手册, 访问 https://wiki.archlinuxcn.org/wiki/WeChat

For user manual and internal document, consult https://wiki.archlinux.org/title/WeChat

KDE Plasma 添加阴影

1.添加阴影

在微信界面，ALT+F3 -> 更多操作 -> 配置特殊窗口设置 -> 添加属性 -> 添加 外观和修正 下面的 无标题栏和边框 -> 将 初始状态应用 改为 强制，将后面的 是 切换称 否 -> 应用

2.去除标题栏

之后微信就有边框阴影了，但是微信多了个标题栏。

设置 -> 颜色和主题 -> 窗口装饰元素 -> 找到你在用的主题右下角的编辑 -> 切换到 特定窗口优先规则 -> 添加 -> 检测窗口属性... -> 选中微信窗口 直到 匹配正则表达式 那里出现 wechat -> 勾选 装饰选项 下面的 隐藏窗口标题栏 -> 确定 -> 应用

依赖和配置也许可以参考合并过来的wechat-bin，之前的这一软件包没有openssl-1.1 protable等额外依赖也没有问题。个人认为wechat-bin的打包其实可能还更合理一点。不过既然都合并过来了，也可以借鉴参考：

# Maintainer: devome <evinedeng@hotmail.com>

_pkgname="wechat"
pkgname="${_pkgname}-bin"
pkgver=4.0.1.7
pkgrel=1
pkgdesc="WeChat from Tencent | 微信官方版"
arch=("x86_64" "aarch64" "loong64")
url="https://linux.weixin.qq.com"
license=("custom:Software License and Service of Tencent Weixin")
provides=("${_pkgname}"{,-universal})
conflicts=("${_pkgname}"{,-universal})
replaces=("${_pkgname}-universal"{,-privilege})
depends=(at-spi2-core jack libpulse libxcomposite libxdamage libxkbcommon-x11 libxrandr mesa nss pango xcb-util-image xcb-util-keysyms xcb-util-renderutil xcb-util-wm)
optdepends=("noto-fonts-cjk: Chinese font support"
            "noto-fonts-emoji: emoji support")
source=("LICENSE-zh_CN.html::https://weixin.qq.com/agreement?lang=zh_CN"
        "LICENSE-zh_HK.html::https://weixin.qq.com/agreement?lang=zh_HK"
        "LICENSE-zh_TW.html::https://weixin.qq.com/agreement?lang=zh_TW"
        "LICENSE-en.html::https://www.wechat.com/mobile/en/service_terms.html")
source_x86_64=("${_pkgname}-${pkgver}-x86_64.deb::https://home-store-packages.uniontech.com/appstore/pool/appstore/c/com.tencent.${_pkgname}/com.tencent.${_pkgname}_${pkgver}_amd64.deb")
source_aarch64=("${_pkgname}-${pkgver}-aarch64.deb::https://home-store-packages.uniontech.com/appstore/pool/appstore/c/com.tencent.${_pkgname}/com.tencent.${_pkgname}_${pkgver}_arm64.deb")
source_loong64=("${_pkgname}-${pkgver}-loong64.deb::https://home-store-packages.uniontech.com/appstore/pool/appstore/c/com.tencent.${_pkgname}/com.tencent.${_pkgname}_${pkgver}_loongarch64.deb")
sha256sums=('SKIP' 'SKIP' 'SKIP' 'SKIP')
sha256sums_x86_64=('bfd5a2a320280148ff35f7a9d36d1ba98f4a685f41df2518fbb10f7636df3bb2')
sha256sums_aarch64=('403fbcc7cb2cd55546e018a8b6e6685aca734c9019b2bdcc09c19b6608e6385e')
sha256sums_loong64=('33eabe2abfd467699d857aa9807fd73c17f058c8d547fdc3141ee078ea68adca')
noextract=("${_pkgname}-${pkgver}-"{x86_64,aarch64,loong64}.deb)
options=("!strip")

prepare() {
    bsdtar -xOf "${_pkgname}-${pkgver}-${CARCH}.deb" data.tar.xz | bsdtar -xmf- --strip-components 4 --exclude "opt/apps/com.tencent.${_pkgname}/info" "opt/apps/com.tencent.${_pkgname}"
    mv "files" "${_pkgname}"
    while read file; do
        if [[ $(file -b "$file") != "ELF "* ]]; then
            chmod -x "$file"
        fi
    done <<< "$(find "${_pkgname}" -type f)"

    sed -e "s|^Icon=.*|Icon=${_pkgname}|" \
        -e "s|^Categories=.*|Categories=Network;InstantMessaging;Chat;|" \
        -e "s|^Exec=.*|Exec=env 'QT_QPA_PLATFORM=wayland;xcb' QT_AUTO_SCREEN_SCALE_FACTOR=1 /usr/bin/${_pkgname} %U|" \
        "entries/applications/com.tencent.${_pkgname}.desktop" > "${_pkgname}.desktop"
}

package() {
    install -Dm644 LICENSE-*          -t "${pkgdir}/usr/share/licenses/${pkgname}"
    install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
    install -dm755 "${pkgdir}/usr/bin"   "${pkgdir}/opt"
    mv "${_pkgname}"                     "${pkgdir}/opt/${_pkgname}"
    ln -s "/opt/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
    for res in 16 32 48 64 128 256; do
        local _png="entries/icons/hicolor/${res}x${res}/apps/com.tencent.${_pkgname}.png"
        install -Dm644 "$_png"           "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/${_pkgname}.png"
    done
}

@devome 受教了。万分感谢~ 刚好是KDE桌面

感谢大佬打包。想问问大佬如何实现通过快捷键，唤出微信窗口的脚本或者操作？

现阶段不能. portable 负责启动 WeChat 并设置正确的环境变量等依赖

@kimiblock 我打字打错了。不是太大的，是不太想有太多的三分依赖。

@yangling 没有. 我不认为 <30KiB 是很大的依赖

portable 有办法做到是可选包吗？不是很喜欢加太大三方的依赖

@Kimiblock Thx, it worked.