PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Daniel S. Palma <contato@danielspalma.adm.br>
# Contributor: Asuka Minato <i at asukaminato dot eu dot org>

pkgname=adspower-global
pkgver=6.12.6
pkgrel=1
pkgdesc="AdsPower - Most Secure Antidetect Browser for Multi-Accounts"
arch=(x86_64)
url="https://www.adspower.com"
license=('custom')
depends=(
    gcc-libs
    glibc
    bash
    electron
    hicolor-icon-theme
)
source=(
    "https://version.adspower.net/software/linux-x64-global/AdsPower-Global-$pkgver-x64.deb"
)
sha256sums=(
    'ca064003d62a9dba30eddf322b0738ade3a5cf5fd9bccfb3a0cb1817681593b7'
)

package() {
    # Extract files from the .deb
    bsdtar -xf data.tar.* -C "$pkgdir"

    # Remove unnecessary files (except the resources/ folder)
    find "$pkgdir/opt" -not -path "*/resources/*" -type f -delete -print
    # Remove files for other architectures (e.g., armv8)
    find "$pkgdir" -name "*armv8*" -delete -print
    # Remove empty directories
    find "$pkgdir" -type d -empty -delete

    # Create the binary launcher
    printf "#!/bin/sh
exec electron /opt/AdsPower\\ Global/resources/app.asar \"\$@\"
" | install -Dm755 /dev/stdin "$pkgdir/usr/bin/adspower-global"

    # Rename and install icons with the new name (adspower-global)
    for size in 16x16 32x32 48x48 64x64 128x128 256x256 512x512 1024x1024; do
        install -Dm644 \
            "$pkgdir/usr/share/icons/hicolor/${size}/apps/adspower_global.png" \
            "$pkgdir/usr/share/icons/hicolor/${size}/apps/adspower-global.png"
    done

    # Create the .desktop shortcut
    mkdir -p "$pkgdir/usr/share/applications"
    printf "[Desktop Entry]
Name=AdsPower Global
Exec=adspower-global
Icon=adspower-global
Terminal=false
Type=Application
Categories=Network;Utility;
" > "$pkgdir/usr/share/applications/adspower-global.desktop"
}