PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer:  Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>

_pkgname="aiwnios"
pkgname="${_pkgname}-git"
pkgver=r679.f1f76a3
pkgrel=1
pkgdesc="A HolyC Compiler/Runtime for 64bit ARM/x86/RISC"
arch=('x86_64' 'aarch64' 'riscv64')
url="https://github.com/nrootconauto/Aiwnios"
license=('BSD-3-Clause')
depends=('glibc' 'sdl2')
makedepends=('git' 'cmake')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
_pkgsrc="Aiwnios"
source=("${_pkgsrc}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgsrc}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
  cd "${srcdir}/${_pkgsrc}"
  cp -f "misc/${_pkgname}.desktop.in" "${_pkgname}.desktop"
  sed -i 's|@CMAKE_INSTALL_PREFIX@|/usr|g' "${_pkgname}.desktop"

  sed -i 's|Vocab.DD|God/Vocab.DD|g' "CMakeLists.txt"
}

build() {
  cd "${srcdir}"
  cmake \
    -G 'Unix Makefiles' \
    -B "${_pkgsrc}/build" \
    -S "${_pkgsrc}" \
    -DCMAKE_BUILD_TYPE:STRING='Release' \
    -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
    -Wno-dev
  cmake --build "${_pkgsrc}/build"
}

package() {
  cd "${srcdir}"
  DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"

  cd "${_pkgsrc}"
  install -Dm644 "README.MD" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
  install -Dm644 "LICENSE"   "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}