PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Omeed Safi <aur@safi.ms>
_pkgname=akr
pkgname="${_pkgname}-git"
pkgver=1.1.2.r50.gf807ab2
pkgrel=1
pkgdesc="Akamai Krypton CLI and SSH Agent"
arch=("x86_64")
url="https://github.com/akamai/akr"
license=("custom:Akamai")
makedepends=("git" "cargo")
provides=("${_pkgname}")
conflicts=("${_pkgname}")
md5sums=("SKIP")

source=("${_pkgname}::git+${url}.git")

pkgver() {
    git -C "${_pkgname}" describe --long --tags | sed 's/-/.r/;s/-/./'
}

prepare() {
    cd "${_pkgname}"
    cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}

build() {
    cd "${_pkgname}"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release --all-features
}

package() {
    cd "${_pkgname}"
    install -Dm0755 -t "${pkgdir}/usr/bin/" "target/release/${_pkgname}"
    install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}