PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=alembic-git
pkgver=1.8.5.r2.gfdb0dcbb
pkgrel=1
pkgdesc="An open framework for storing and sharing scene data"
arch=('i686' 'x86_64')
url="https://www.alembic.io/"
license=('BSD' 'custom')
depends=('glibc' 'hdf5' 'imath')
makedepends=('git' 'cmake')
provides=("alembic=$pkgver")
conflicts=('alembic')
source=("git+https://github.com/alembic/alembic.git")
sha256sums=('SKIP')


pkgver() {
  cd "alembic"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "alembic"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DUSE_HDF5=ON \
    ./
  make -C "_build"
}

check() {
  cd "alembic"

  make -C "_build" test
}

package() {
  cd "alembic"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE.txt" -t "$pkgdir/usr/share/licenses/alembic"
}