PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Contributor: Mark Foxwell <fastfret79@archlinux.org.uk>
# Contributor: Nicolas Pouillard [https://nicolaspouillard.fr]
# Contributor: seschwar -- contact via Arch Linux forum or AUR
# Contributor: Ian Denhardt <ian@zenhack.net>
# Contributor: Joakim Reinert <mail+aur@jreinert.com>
# Maintainer: Dylan Baker <dylan@pnwbakers.com>

_gitname=alot
pkgname=alot-git
pkgrel=1
pkgver=r3394.4a671186
pkgdesc="terminal-based MUA for the notmuch mail system"
arch=(any)
url="https://github.com/pazz/alot"
license=('GPL3')
depends=(notmuch
         python
         python-gpgme
         python-magic
         python-configobj
         python-urwid
         python-urwidtrees
         python-twisted
         python-setuptools)
makedepends=(python-sphinx git)
provides=(alot)
conflicts=(alot)
options=(!emptydirs !strip libtool staticlibs zipman)
source=('git+https://github.com/pazz/alot.git')
md5sums=(SKIP)

pkgver() {
  cd "$srcdir/$_gitname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/$_gitname"

    # The archlinux package python-magic's egg calls itself
    # "file-magic", as opposed to the python-magic on pypi. The
    # result is that the alot executable can't find the module, so we patch
    # setup.py to fix the dependency:
    sed -i -e 's/python-magic/file-magic/' setup.py
    python setup.py build
    make SPHINXBUILD=sphinx-build PYTHON=python -C docs man html
}

package() {
    cd "$srcdir/$_gitname"
    python setup.py install --optimize=1 --root="$pkgdir"

    # Delete tests
    rm -rvf "$pkgdir/usr/lib/python3.6/site-packages/tests"

    # Install extra data
    install -Dm644 extra/completion/alot-completion.zsh \
        "$pkgdir/usr/share/zsh/functions/_alot"
    install -dm755 "$pkgdir/usr/share/alot/themes"
    install -Dm644 extra/themes/{mutt,solarized_light,solarized_dark,sup,tomorrow} \
        "${pkgdir}/usr/share/alot/themes"
    install -dm755 "$pkgdir/usr/share/doc/$pkgname"
    cp -a docs/build/html/* "$pkgdir/usr/share/doc/$pkgname"
    install -Dm644 docs/build/man/alot.1 "$pkgdir/usr/share/man/man1/alot.1"
}