PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Maxime Gauduin <alucryd@archlinux>org>
# Contributor: quietvoid <tcChlisop0@gmail.com>

_android_arch=aarch64

pkgname=android-${_android_arch}-libdovi
pkgver=3.3.1
pkgrel=1
arch=('any')
pkgdesc="Library to read and write Dolby Vision metadata (Android ${_android_arch})"
url='https://github.com/quietvoid/dovi_tool/tree/main/dolby_vision'
license=('MIT')
groups=('android-libdovi')
depends=('android-ndk')
makedepends=('android-rust')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://github.com/quietvoid/dovi_tool/archive/refs/tags/libdovi-${pkgver}.tar.gz")
md5sums=('47ea97db5c7875175b035b34de9d224c')

prepare() {
    cd "${srcdir}/dovi_tool-libdovi-${pkgver}"
    source android-rust-env ${_android_arch}
    android_rust_prepare

    cargo fetch \
        --manifest-path dolby_vision/Cargo.toml
}

build() {
    cd "${srcdir}/dovi_tool-libdovi-${pkgver}"
    source android-rust-env ${_android_arch}

    android_cargo_cbuild \
        --manifest-path dolby_vision/Cargo.toml
}

package() {
    cd "${srcdir}/dovi_tool-libdovi-${pkgver}"
    source android-rust-env ${_android_arch}

    android_cargo_cinstall \
        --manifest-path dolby_vision/Cargo.toml \
        --destdir "${pkgdir}"
    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
    ${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a
}