blob: d0240115763e1830ce7188b3e9495d091bcb38ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: drakkan <nicola.murino at gmail dot com>
_android_arch=aarch64
pkgname=android-${_android_arch}-pcre
pkgver=8.45
pkgrel=3
pkgdesc="A library that implements Perl 5-style regular expressions (Android ${_android_arch})"
arch=('any')
url="http://www.pcre.org/"
license=("BSD")
groups=('android-pcre')
depends=('android-ndk')
options=(!strip !buildflags staticlibs !emptydirs)
makedepends=('android-configure'
"android-${_android_arch}-bzip2"
"android-${_android_arch}-zlib")
optdepends=("android-${_android_arch}-bzip2"
"android-${_android_arch}-zlib")
source=("http://downloads.sourceforge.net/pcre/pcre-${pkgver}.tar.bz2"{,.sig}
'0001-Add-riscv64-support.patch'
'0001-Remove-arch-restrictions.patch')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8') # Philip Hazel
md5sums=('4452288e6a0eefb2ab11d36010a1eebb'
'SKIP'
'4c20c5f8250090062a2bba23459a007c'
'18e9da1810e8fde1ce9009fc4c1b3c12')
prepare() {
cd "${srcdir}/pcre-${pkgver}"
patch -Np1 -i ../0001-Add-riscv64-support.patch
#patch -Np1 -i ../0001-Remove-arch-restrictions.patch
}
build() {
cd "${srcdir}/pcre-${pkgver}"
source android-env ${_android_arch}
export LIBS="-L${ANDROID_PREFIX_LIB}"
export CPPFLAGS="-I${ANDROID_PREFIX_INCLUDE}"
android-${_android_arch}-configure \
--enable-jit \
--enable-pcre16 \
--enable-pcre32 \
--enable-pcregrep-libz \
--enable-pcregrep-libbz2
make $MAKEFLAGS
}
package() {
cd "${srcdir}/pcre-${pkgver}"
source android-env ${_android_arch}
make DESTDIR="${pkgdir}" install
rm -r "${pkgdir}/${ANDROID_PREFIX_BIN}"
rm -r "${pkgdir}/${ANDROID_PREFIX_SHARE}"
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a
}
|