blob: 1f083c4828349b5a42b9e4270301a263961ebf96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: drakkan <nicola.murino at gmail dot com>
_android_arch=armv7a-eabi
pkgname=android-${_android_arch}-nettle
pkgver=3.10
pkgrel=2
pkgdesc="A low-level cryptographic library (Android ${_android_arch})"
arch=('any')
url="http://www.lysator.liu.se/~nisse/nettle"
license=("GPL2")
depends=("android-${_android_arch}-gmp")
makedepends=('android-configure')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://ftp.gnu.org/gnu/nettle/nettle-${pkgver}.tar.gz"
'0001-Unversioned-libs.patch')
md5sums=('c61453139d5fb44e9cdcc5b684b26e55'
'604ae2c58164024fbe4debc2aa6eb6cc')
prepare() {
cd "$srcdir/nettle-$pkgver"
patch -Np1 -i ../0001-Unversioned-libs.patch
}
build() {
cd "$srcdir/nettle-$pkgver"
source android-env ${_android_arch}
android-${_android_arch}-configure \
--enable-ld-version-script=no \
--disable-documentation
make $MAKEFLAGS
}
package() {
cd "${srcdir}/nettle-${pkgver}"
source android-env ${_android_arch}
make DESTDIR="$pkgdir" install
rm -rf "${pkgdir}/${ANDROID_PREFIX_BIN}"
rm -rf "${pkgdir}/${ANDROID_PREFIX_SHARE}"
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a
}
|