PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Askhat Bakarov <sirocco{at}ngs{dot}ru>

pkgname=android-file-transfer-git
pkgver=4.3.r13.g2a48d30
pkgrel=2
pkgdesc="An interactive MTP client implemented in C++ using Qt toolkit"
arch=(x86_64 i686)
url="https://github.com/whoozle/android-file-transfer-linux"
license=(LGPL2.1)
depends=(qt5-base fuse2 hicolor-icon-theme taglib)
makedepends=(cmake git qt5-tools ninja pybind11)
provides=(android-file-transfer)
conflicts=(android-file-transfer android-file-transfer-linux)
source=("git+https://github.com/whoozle/android-file-transfer-linux.git")
sha256sums=('SKIP')

pkgver() {
  cd "android-file-transfer-linux"
  git describe --long --tags --exclude continuous | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cmake -B build -S "android-file-transfer-linux" -Wno-dev \
    -G Ninja \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_INSTALL_PREFIX=/usr \

  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}