blob: 801e445cefa6709b1db2150d99821f349daf3958 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>
_android_arch=riscv64
pkgname=android-${_android_arch}-sord
pkgver=0.16.18
pkgrel=1
arch=('any')
pkgdesc="A lightweight C library for storing RDF data in memory (Android ${_android_arch})"
url="https://drobilla.net/software/sord.html"
license=('ISC')
groups=('android-sord')
depends=("android-${_android_arch}-pcre2"
"android-${_android_arch}-serd"
"android-${_android_arch}-zix")
makedepends=('android-meson'
"android-${_android_arch}-pcre2"
"android-${_android_arch}-serd"
"android-${_android_arch}-zix")
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://download.drobilla.net/sord-${pkgver}.tar.xz")
md5sums=('8c7bf82dfa5bd7d6906ded54032f8a64')
build() {
cd "${srcdir}/sord-${pkgver}"
source android-env ${_android_arch}
android-${_android_arch}-meson build \
-D docs=disabled \
-D tests=disabled \
-D tools=disabled
ninja -C build
}
package() {
cd "${srcdir}/sord-${pkgver}"
source android-env ${_android_arch}
DESTDIR="${pkgdir}" ninja -C build install
${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a || true
${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
${ANDROID_RANLIB} "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a || true
}
|