blob: 9d141da4b980500a0077700e4f8699182fbd068d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_pkgname="appimagetool"
pkgname="${_pkgname}-git"
pkgver=r61.c247c92
pkgrel=2
pkgdesc="Low-level tool to generate an AppImage from an existing AppDir"
arch=('aarch64' 'armv7h' 'i686' 'x86_64')
url="https://github.com/AppImage/${_pkgname}"
license=('MIT')
depends=('curl' 'gcc-libs' 'glib2' 'glibc' 'gpgme' 'hicolor-icon-theme'
'libgcrypt' 'squashfs-tools')
makedepends=('cmake>=3.21' 'git')
optdepends=('zsync: for binary delta updates')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
_pkgsrc="${_pkgname}"
source=("${_pkgsrc}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgsrc}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
export CFLAGS+=" -Wno-error=int-conversion"
local cmake_options=(
-G 'Unix Makefiles'
-B "${_pkgsrc}/build"
-S "${_pkgsrc}"
-Wno-dev
-DCMAKE_BUILD_TYPE:STRING='None'
-DCMAKE_INSTALL_PREFIX:PATH='/usr'
)
cd "${srcdir}"
cmake "${cmake_options[@]}"
cmake --build "${_pkgsrc}/build"
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"
cd "${_pkgsrc}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|