PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Bruno Silva <brunofernandes at ua dot pt>

pkgname=asn1c-mouse07410-git
_pkgname=asn1c
pkgver=v1.0.0.r60.g165e8504
pkgrel=1
pkgdesc="An ASN.1 compiler mouse07410 Fork from vlm/asn1c"
arch=('i686' 'x86_64')
url="http://lionet.info/asn1c/blog/"
license=('GPL3')
depends=(glibc)
makedepends=(glibc git autoconf gcc flex automake libtool bison)
optdepends=()
provides=('asn1c')
conflicts=('asn1c')
options=('!strip')
source=(git+https://github.com/mouse07410/asn1c.git#branch=vlm_master)
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgname}"
  ( set -o pipefail
    git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
  )
}

build() {
	cd "${srcdir}/${_pkgname}"
	autoreconf -iv && ./configure --prefix=/usr
	make
}

package() {
	cd "${srcdir}/${_pkgname}"
	make DESTDIR="$pkgdir/" install
}