blob: e192756b697bf30d9fb6681e8f2e5d5e795cc66d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Leonidas Spyropoulos <artafinde at gmail dot com>
pkgname=auracle-git
_pkgname="${pkgname%-git}"
pkgver=r420.f4cebb5
pkgrel=1
pkgdesc='A flexible client for the AUR'
arch=('x86_64' 'i686')
url="https://github.com/falconindy/auracle"
license=('MIT')
depends=('pacman' 'libcurl.so' 'libsystemd')
makedepends=('meson' 'git' 'perl' 'systemd')
checkdepends=('python' 'fakechroot' 'gtest')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+$url")
b2sums=('SKIP')
pkgver() {
cd "$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$_pkgname"
local filename
for filename in "${source[@]}"; do
if [[ "$filename" =~ \.patch$ ]]; then
echo "Applying patch ${filename##*/}"
patch -p1 -N -i "$srcdir/${filename##*/}"
fi
done
local meson_args=(
--prefix=/usr
--libexecdir=lib
--sbindir=bin
--buildtype=plain
--default-library=static
-Db_pie=true
)
[[ -d build ]] && meson_args+=(--wipe)
meson setup build "${meson_args[@]}"
}
build() {
cd "$_pkgname"
meson compile -C build
}
check() {
cd "$_pkgname"
meson test -C build
}
package () {
cd "$_pkgname"
DESTDIR="$pkgdir" meson install -C build --skip-subprojects
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: et ts=2 sw=2
|