PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: hrdl <aur@hrdl.eu>
# Contributor: danb (danb) <danb (at) hasi.it>

pkgname=avizo-git
_pkgname=avizo
pkgver=r93.9cd5319
pkgrel=1
pkgdesc="A neat notification daemon"
arch=("x86_64")
url="https://github.com/misterdanb/avizo"
license=("GPL")
depends=(
  "alsa-utils"
  "dbus"
  "gobject-introspection"
  "gtk-layer-shell"
  "gtk3"
)
optdepends=(
  "brightnessctl: for helper script lightctl"
  "light: for helper script lightctl"
  "pamixer: for helper script volumectl"
)
makedepends=(
  "git"
  "vala"
  "meson"
  "ninja"
)
provides=('avizo')
conflicts=('avizo')

source=("$_pkgname::git+https://github.com/misterdanb/avizo.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$_pkgname"

  arch-meson . build
  meson compile -C build
}

check() {
  cd "$_pkgname"

  meson test -C build
}

package() {
  cd "$_pkgname"

  meson install -C build --destdir "$pkgdir"
}