blob: 808bdb1f472ff380a23fd83ac75215176b6be0fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Contributor: Sven-Hendrik Haase <svenstaro@archlinux.org>
# Contributor: Konstantin Gizdov <arch@kge.pw>
# Contributor: Frederik Schwan <frederik dot schwan at linux dot com>
# Contributor: Simon Legner <Simon.Legner@gmail.com>
pkgname=bazel5
pkgver=5.4.1
pkgrel=1
pkgdesc='Correct, reproducible, and fast builds for everyone, version 5.x'
arch=('x86_64')
license=('Apache')
url='https://bazel.build/'
depends=('java-environment=11' 'libarchive' 'zip' 'unzip')
makedepends=('git' 'protobuf' 'python' 'gcc12')
provides=('bazel')
conflicts=('bazel')
options=('!distcc' '!strip')
source=("https://github.com/bazelbuild/bazel/releases/download/${pkgver}/bazel-${pkgver}-dist.zip")
b2sums=('5a5898b29ea14c7b660f8124a7f4aa795a3c2205a89aadd3d865c792dae59cd933ca376eb52d8bf3d53ed13704a3284e96bce2b9de702a84cb4f6d0b2b821380')
build() {
CC=/usr/bin/gcc-12 \
CXX=/usr/bin/g++-12 \
EMBED_LABEL=$pkgver EXTRA_BAZEL_ARGS="--host_javabase=@local_jdk//:jdk" ./compile.sh
CC=/usr/bin/gcc-12 \
CXX=/usr/bin/g++-12 \
./output/bazel build scripts:bazel-complete.bash
cd output
./bazel shutdown
}
package() {
install -Dm755 "${srcdir}/scripts/packages/bazel.sh" "${pkgdir}/usr/bin/bazel"
install -Dm755 "${srcdir}/output/bazel" "${pkgdir}/usr/bin/bazel-real"
install -Dm644 "${srcdir}/bazel-bin/scripts/bazel-complete.bash" "${pkgdir}/usr/share/bash-completion/completions/bazel"
install -Dm644 "${srcdir}/scripts/zsh_completion/_bazel" "${pkgdir}/usr/share/zsh/site-functions/_bazel"
mkdir -p "${pkgdir}/usr/share/bazel"
for d in examples third_party tools; do
cp -r "${srcdir}/${d}" "${pkgdir}/usr/share/bazel/"
done
}
|