blob: dbbc4cf6e5b209dd3687e8336f57e393c923f1bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=brioche
pkgver=0.1.3
pkgrel=1
pkgdesc='a package manager and build tool for building and running complex software projects'
arch=(x86_64)
url="https://$pkgname.dev"
_url="https://github.com/brioche-dev/$pkgname"
license=(MIT)
depends=(gcc-libs
glibc)
makedepends=(cargo)
options=(!lto)
_archive="$pkgname-$pkgver"
source=("$_url/archive/v$pkgver/$_archive.tar.gz")
sha256sums=('e274ae17f84bfd1b67925e7f5471614563bfb34f3a2262e013ed7b86520d7fb3')
prepare() {
cd "$_archive"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
_srcenv() {
cd "$_archive"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
}
build() {
_srcenv
cargo build --frozen --release --all-features
}
check() {
_srcenv
local skipped=(
test_eval_async
test_eval_basic
test_eval_brioche_glob
test_eval_brioche_glob_submodule
test_eval_brioche_include_directory
test_eval_brioche_include_file
test_eval_custom_export
test_eval_import_dep
test_eval_import_local
test_eval_serialize_async
test_script_ops_version
)
cargo test --frozen --all-features -- ${skipped[@]/#/--skip }
}
package() {
cd "$_archive"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.md
}
|