PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: WinStuff <justwinstuff@gmail.com>
pkgname=bsky-desktop
pkgver=1.0.1
pkgrel=1
pkgdesc="An unofficial desktop client for Bluesky"
arch=('x86_64')
url="https://github.com/enderfoxbg/bsky"
license=('GPL3')
depends=('gtk3' 'nss' 'libxss')
makedepends=('npm' 'nodejs' 'git')
source=("bsky-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('SKIP')

build() {
    cd "bsky-$pkgver"
    npm install
    NODE_ENV=production npm run build:aur
}

package() {
    cd "bsky-$pkgver"
    install -d "$pkgdir/usr/lib/$pkgname"
    cp -r dist/linux-unpacked/* "$pkgdir/usr/lib/$pkgname/"
    install -Dm644 "icons/icon.png" "$pkgdir/usr/share/pixmaps/bsky-desktop.png"
    install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/bsky-desktop.desktop" << END
[Desktop Entry]
Name=Bluesky
Comment=An unofficial desktop client for Bluesky
Exec=/usr/bin/bsky-desktop
Icon=bsky-desktop
Terminal=false
Type=Application
Categories=Network;InstantMessaging;
END

    install -d "$pkgdir/usr/bin"
    ln -s "/usr/lib/$pkgname/bsky" "$pkgdir/usr/bin/bsky-desktop"
}