blob: af66c38b2f60f766c27907841f49703d722e7922 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Artem Klevtsov <a.a.klevtsov [at] gmail [dot] com>
# Co-maintainer: Nebulosa <nebulosa2007 at yandex dot ru>
pkgname=byedpi
pkgver=0.16.6
pkgrel=1
pkgdesc="A simple and fast software designed to bypass Deep Packet Inspection"
arch=(aarch64 armv6 armv7l i686 x86_64)
url="https://github.com/hufrea/$pkgname"
license=(MIT)
depends=(glibc)
options=(!debug)
backup=("etc/$pkgname.conf")
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('8511f7e85b5fc840c84bf5093149632bb0b8d34b2fe5f9430cb675ef3235b4e5feff9e6b0c65a2fa509f6e3aa0cc90b2c07c2ef3ebc0f555f390bae5e02446dd')
b2sums=('d276699e30c701645655b04a84811d1b33fc7aa63f7a5abd7883ccd83d22aeed1ca2c94b0bd5be55ef8da02f0ed4c398f7d0e83860c5d54a45fd9006d3fe3a3f')
prepare() {
sed -i 's|ciadpi|/usr/bin/ciadpi|' $pkgname-$pkgver/dist/linux/$pkgname.service
}
build() {
cd $pkgname-$pkgver
make
}
package() {
cd $pkgname-$pkgver
install -vDm 644 dist/linux/$pkgname.conf -t "$pkgdir"/etc/
install -vDm 755 ciadpi -t "$pkgdir"/usr/bin/
install -vDm 644 dist/linux/$pkgname.service -t "$pkgdir"/usr/lib/systemd/system/
install -vDm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}
|