PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Fangrui Song <i at maskray.me>
# Co-Maintainer: Shengyu Zhang <la@archlinuxcn.org>

_pkgname=ccls
pkgname=${_pkgname}-clang-git
pkgver=20220417
pkgrel=1
pkgdesc='C/C++ language server supporting cross references, hierarchies, completion and semantic highlighting, build against llvm-git and clang-git'
arch=('x86_64')
url='https://github.com/MaskRay/ccls'
license=('Apache')
depends=('clang-git' 'llvm-libs')
provides=("$_pkgname" "${pkgname}-git")
conflicts=("$_pkgname" "${pkgname}-git")
makedepends=("cmake" "git" "llvm-git" "polly-git")
source=('git+https://github.com/MaskRay/ccls.git')
md5sums=('SKIP')

pkgver() {
  cd $_pkgname
  TZ=UTC date -d @$(git log -1 --format=%ct) +%Y%m%d
}

prepare() {
  cd $_pkgname
  git submodule update --init
}

build() {
  cd $_pkgname
  cmake -H. -Bbuild -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_CXX_COMPILER=c++ \
        -DCLANG_LINK_CLANG_DYLIB=on \
        -DCMAKE_BUILD_TYPE='None' \
        -DUSE_SYSTEM_RAPIDJSON=on
  cmake --build build
}

package() {
  cd $_pkgname/build
  make DESTDIR="$pkgdir" install
}