blob: 35223ba2785b728b1a35b1ceca4757f37ff6829c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Contributor: Krzysztof Saczuk <zakku@zakku.eu>
# Contributor: Maxim Baz <cerebro@maximbaz.com>
pkgname=cerebro-git
_pkgname=Cerebro
pkgver=0.11.0.r22.gbcabb5b
_electronversion=20
_nodeversion=16
pkgrel=1
pkgdesc='An open-source launcher to improve your productivity and efficiency.Use system-wide electron.'
arch=('any')
url='https://www.cerebroapp.com/'
_ghurl="https://github.com/cerebroapp/cerebro"
license=('MIT')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}=${pkgver%.r*}")
depends=(
"electron${_electronversion}"
)
makedepends=(
'npm'
'yarn'
'git'
'nvm'
'gendesk'
)
source=(
"${pkgname%-git}.git::git+${_ghurl}.git"
"${pkgname%-git}.sh"
)
sha256sums=('SKIP'
'291f50480f5a61bc9c68db7d44cd0412071128706baa868a9cb854f8779a1980')
pkgver() {
cd "${srcdir}/${pkgname//-/.}"
set -o pipefail
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
_ensure_local_nvm() {
local NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install "${_nodeversion}"
nvm use "${_nodeversion}"
}
build() {
sed -e "
s/@electronversion@/${_electronversion}/g
s/@appname@/${pkgname%-git}/g
s/@runname@/app.asar/g
s/@cfgdirname@/${_pkgname}/g
s/@options@//g
" -i "${srcdir}/${pkgname%-git}.sh"
_ensure_local_nvm
gendesk -q -f -n --pkgname="${pkgname%-git}" --pkgdesc="${pkgdesc}" --categories="Utility" --name="${_pkgname}" --exec="${pkgname%-git} %U"
cd "${srcdir}/${pkgname%-git}.git"
electronDist="/usr/lib/electron${_electronversion}"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
HOME="${srcdir}/.electron-gyp"
mkdir -p "${srcdir}/.electron-gyp"
if [[ "$(curl -s ipinfo.io/country)" == *"CN"* ]]; then
{
echo -e '\n'
echo 'registry "https://registry.npmmirror.com"'
echo 'disturl "https://registry.npmmirror.com/-/binary/node/"'
echo 'electron_mirror "https://registry.npmmirror.com/-/binary/electron/"'
echo 'electron_builder_binaries_mirror "https://registry.npmmirror.com/-/binary/electron-builder-binaries/"'
echo "cacheFolder "${srcdir}"/.yarn/cache"
echo "pluginsFolder "${srcdir}"/.yarn/plugins"
echo "globalFolder "${srcdir}"/.yarn/global"
echo 'useHardlinks true'
#echo 'buildFromSource true'
echo 'linkWorkspacePackages true'
echo 'fetchRetries 3'
echo 'fetchRetryTimeout 10000'
} >> .yarnrc
sed -i "s/registry.yarnpkg.com/registry.npmmirror.com/g" yarn.lock
fi
sed -i "s/\"electron\": \"[^\"]*\"/\"electron\": \"${SYSTEM_ELECTRON_VERSION}\"/g" package.json
NODE_ENV=development yarn install --cache-folder "${srcdir}/.yarn_cache"
NODE_ENV=production yarn run build
NODE_ENV=production npm exec -c "electron-builder --linux dir -c.electronDist=${electronDist}"
}
package() {
install -Dm755 "${srcdir}/${pkgname%-git}.sh" "${pkgdir}/usr/bin/${pkgname%-git}"
install -Dm644 "${srcdir}/${pkgname%-git}.git/release/linux-"*/resources/app.asar -t "${pkgdir}/usr/lib/${pkgname%-git}"
_icon_sizes=(16x16 32x32 48x48 128x128 256x256 512x512 1024x1024)
for _icons in "${_icon_sizes[@]}";do
install -Dm644 "${srcdir}/${pkgname%-git}.git/build/icons/${_icons}.png" \
"${pkgdir}/usr/share/icons/hicolor/${_icons}/apps/${pkgname%-git}.png"
done
install -Dm644 "${srcdir}/${pkgname%-git}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${srcdir}/${pkgname%-git}.git/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|