PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Contributer: sukanka <su975853527 AT gmail dot com>
# Maintainer: devome <evinedeng@hotmail.com>

pkgname=citespace
pkgver=6.3.1
pkgrel=1
pkgdesc="A widely used tool for visual exploration of scientific literature."
arch=('any')
url="https://citespace.podia.com"
license=('unknown')
depends=('java-runtime>=11.0.11')
makedepends=('p7zip' 'libicns')
optdepends=('mysql: for data cleansing')
source=("${pkgname}-${pkgver}.dmg::https://zenlayer.dl.sourceforge.net/project/citespace/6.3.R1%20Basic%20%282.14.2024%20-%2012.31.2025%29/CiteSpace-6.3.1.dmg?viasf=1"
        "${pkgname}.desktop"
        "${pkgname}.sh")
sha256sums=('c52f18cc9c714f080935be13e054cec36ebcb988e6f1385185c7329d3297aaaf'
            '5256f6866d830da93fd5439d45ae8b35f45806d19e7c86830e8d2db07fa5c83d'
            '1956b9cf79dc93834adcdff147337bbdbe9810074997e2e89c31073025baa902')

prepare() {
    7z x "${pkgname}-${pkgver}.dmg"
    mv CiteSpace/CiteSpace.app/Contents/app/*.jar "${pkgname}.jar"
    mv CiteSpace/CiteSpace.app/Contents/Resources/*.icns "${pkgname}.icns"
    icns2png -x "${pkgname}.icns"
    mv *.png "${pkgname}.png"
}

package(){
    install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
    install -Dm644 "${pkgname}.jar"     "${pkgdir}/usr/share/java/${pkgname}.jar"
    install -Dm644 "${pkgname}.png"     "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${pkgname}.png"
    install -Dm755 "${pkgname}.sh"      "${pkgdir}/usr/bin/${pkgname}"
}