PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Maintainer: Alex Hirzel <alex at hirzel period us>
# Contributor: Maarten de Boer <maarten@cloudstek.nl>
# Contributor: Yakumo Saki <yakumo at ziomatrix dot org>
# Contributor: Xuanwo <xuanwo@archlinucn.org>
pkgname=clickup
pkgver=3.5.76
pkgrel=1
pkgdesc="Desktop app for clickup.com"
arch=('x86_64')
url="https://clickup.com"
license=('CustomLicense')
depends=(
	'alsa-lib'
	'dbus-glib'
	'gtk3'
	'libdbusmenu-gtk2'
	'libindicator-gtk2'
	'libsecret'
	'libxkbfile'
	'nss'
)
makedepends=('sed')
options=('!strip')

_filename="$pkgname-desktop-$pkgver-x86_64.AppImage"

source=("${_filename}::https://desktop.clickup.com/linux"
        "terms.html::https://clickup.com/terms")

sha256sums=('0e73f67aa5b2d035df3925760bdc25b173c3922b82d04d03cf87f029f2ccba9c'
            'SKIP')

prepare() {
    rm -rf squashfs-root
    chmod +x $_filename
    ./$_filename --appimage-extract

    # Fix directory permissions (read + execute)
    find squashfs-root -type d -exec chmod a+rx {} \;
}

package() {
    cd "${srcdir}/squashfs-root"

    # Symlink to /usr/bin
    install -dm0755 "${pkgdir}/usr/bin"
    ln -s /opt/clickup/desktop "${pkgdir}/usr/bin/clickup"

    # Desktop entry and icons
    install -Dm0644 desktop.desktop -T "${pkgdir}/usr/share/applications/ClickUp.desktop"
    sed -i -e "s|Exec=.\+|Exec=/usr/bin/${pkgname} %U|" "${pkgdir}/usr/share/applications/ClickUp.desktop"

    # Terms and licenses
    install -Dm0644 "${srcdir}/terms.html" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    install -Dm0644 LICENSE.electron.txt -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    install -Dm0644 LICENSES.chromium.html -t "${pkgdir}/usr/share/licenses/${pkgname}/"

    # Icons
    icons=(1024x1024 512x512 256x256 128x128 64x64 48x48 32x32 16x16)

    for size in "${icons[@]}"; do
        install -Dm0644 usr/share/icons/hicolor/${size}/apps/desktop.png -T "${pkgdir}/usr/share/icons/hicolor/${size}/apps/ClickUp.png"
    done

    # AppDir contents
    cd "${srcdir}"
    install -dm0755 "${pkgdir}/opt"
    mv squashfs-root "${pkgdir}/opt/clickup"
    chmod 755 "${pkgdir}/opt/clickup"
    chmod a+rX "${pkgdir}/opt/clickup/"

    # Clean up files
    rm -r "${pkgdir}/opt/clickup/usr/share/"
    rm "${pkgdir}/opt/clickup/AppRun" "${pkgdir}/opt/clickup/desktop.desktop"
    rm "${pkgdir}/opt/clickup/desktop.png" "${pkgdir}/opt/clickup/.DirIcon"
    rm "${pkgdir}/opt/clickup/LICENSE.electron.txt" "${pkgdir}/opt/clickup/LICENSES.chromium.html"
}