PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Adrian Perez de Castro <aperez@igalia.com>
pkgdesc='WPE launcher and webapp container'
pkgname=cog
pkgver=0.18.4
pkgrel=1
url=https://github.com/Igalia/cog
arch=(i686 x86_64 aarch64 armv7l armv7h)
groups=(wpe)
conflicts=(cog-git)
depends=('wpewebkit>=2.42.5-3' 'wpebackend-fdo>=1.10.0' libinput libmanette)
makedepends=(meson wayland-protocols libxcb libxkbcommon-x11 gtk4 weston)
optdepends=('libxcb: x11 platform support'
            'libxkbcommon-x11: x11 platform support'
			'gtk4: gtk4 platform support')
license=(MIT)
source=("https://wpewebkit.org/releases/${pkgname}-${pkgver}.tar.lz"
        "https://wpewebkit.org/releases/${pkgname}-${pkgver}.tar.lz.asc")
validpgpkeys=('5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')

md5sums=(fe5cc3b56a84dc67caa94cf0d3a9184e SKIP)
sha1sums=(68de4829c2894c02c74e432173747c26ca8641ed SKIP)
sha256sums=(68c13e16d85ace8db2d67ec1d829fb74fe7f941510cc894cd08f4227cbba705d SKIP)

build () {
	rm -rf _build
	arch-meson \
		-D documentation=false \
		-D manpages=true \
		-D platforms=drm,gtk4,headless,wayland,x11 \
		-D programs=true \
		-D wayland_weston_content_protection=true \
		-D wayland_weston_direct_display=true \
		-D wpe_api=2.0 \
		_build "${pkgname}-${pkgver}"
	meson compile -C _build
}

package () {
	meson install -C _build --destdir "${pkgdir}"

	install -Dm644 "${pkgname}-${pkgver}/COPYING" \
		"${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}