PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-ext-applet-apps-menu-git
_app_id=dev.dominiccgeh.CosmicAppletAppsMenu
pkgver=0.1.6.r17.gcafd314
pkgrel=1
pkgdesc="Category based menu for apps for COSMIC™️ DE"
arch=('x86_64')
url="https://github.com/leb-kuchen/cosmic-ext-applet-apps-menu"
license=('GPL-3.0-or-later')
depends=('cosmic-applets')
makedepends=('cargo' 'git')
provides=("${pkgname%-git}")
conflicts=(
  "${pkgname%-git}"
  'cosmic-applet-apps-menu-git'
  'apps-menu-applet-for-cosmic_tm-git'
  'apps-menu-applet-for-cosmic-git'
)
source=('git+https://github.com/leb-kuchen/cosmic-ext-applet-apps-menu.git')
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${pkgname%-git}"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "${pkgname%-git}"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release --all-features
}

package() {
  cd "${pkgname%-git}"
  install -Dm755 target/release/cosmic-applet-apps-menu \
    "$pkgdir/usr/bin/${pkgname%-git}"
  install -Dm644 "data/${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
  install -Dm644 data/icons/scalable/apps/${_app_id}.svg -t \
    "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
}