PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

pkgname=cosmic-ext-applet-ollama-git
pkgver=r96.d1b3238
pkgrel=1
pkgdesc="Ollama applet for COSMIC Desktop"
arch=('x86_64')
url="https://github.com/elevenhsoft/cosmic-ext-applet-ollama"
license=('GPL-3.0-or-later')
depends=('cosmic-applets')
makedepends=('cargo' 'git')
provides=("${pkgname%-git}" "cosmic-applet-ollama")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/elevenhsoft/cosmic-ext-applet-ollama')
sha256sums=('SKIP')
options=(!lto)

pkgver() {
  cd "${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${pkgname%-git}"
  export CARGO_HOME="$srcdir/cargo-home"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "${pkgname%-git}"
  export CARGO_HOME="$srcdir/cargo-home"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release --all-features
}

package() {
  cd "${pkgname%-git}"
  install -Dm755 target/release/${pkgname%-git} -t "$pkgdir/usr/bin/"
  install -Dm644 data/io.github.elevenhsoft.CosmicExtAppletOllama.desktop -t \
    "$pkgdir/usr/share/applications/"
  install -Dm644 data/icons/scalable/apps/io.github.elevenhsoft.CosmicExtAppletOllama-symbolic.svg -t \
    "$pkgdir/usr/share/icons/Cosmic/scalable/apps/"
}