blob: c864763c8e95fd82470bc637e7489f646638c51e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Attila Greguss <floyd0122@gmail.com>
pkgname=cosmic-ext-applet-system-monitor-git
pkgver=r28.aa64824
pkgrel=2
pkgdesc="System Monitor for the COSMIC™ desktop"
arch=('x86_64')
url="https://github.com/D-Brox/cosmic-ext-applet-system-monitor"
license=('GPL-3.0')
depends=(
'cosmic-applets'
'fontconfig'
'libxkbcommon'
)
makedepends=(
'cargo'
'git'
'just'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/D-Brox/cosmic-ext-applet-system-monitor")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
just build-release --frozen
}
package() {
cd "${pkgname%-git}"
just rootdir="$pkgdir" install
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|