PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: oldkingOK <oldkingok.creeper@gmail.com>

pkgname=d4m-git
_pkgname=${pkgname%-git}
pkgver=r191.4b493ff
pkgrel=1
pkgdesc="Project Diva MegaMix+ mod manager"
arch=('any')
license=('MIT')
url='https://github.com/brod8362/d4m'
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
depends=(
    'libarchive'
    'pyside6'
    'python-requests'
    'python-colorama'
    'python-toml'
    'python-simple-term-menu'
    'python-vdf'
    'python-libarchive'
    'python-appdirs'
    'python-packaging'
)
makedepends=(
    'python-build'
    'python-installer'
    'python-wheel'
    'python-pip'
    'git'
    'python-setuptools'
    'python-setuptools-scm'
    'python-setuptools-git-versioning-git'
)

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/$pkgname"
    python -m build --no-isolation
}

package() {
    cd "$srcdir/$pkgname"

    install -D resources/logo.svg "$pkgdir/usr/share/pixmaps/d4m.svg"
    install -D aur/d4m.desktop "$pkgdir/usr/share/applications/d4m.desktop"
    python -m installer --destdir="$pkgdir" dist/*.whl
}