PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=dbxfs
pkgver=2.0.1
pkgrel=1
pkgdesc="User-space file system for Dropbox"
arch=('x86_64')
url="https://thelig.ht/code/dbxfs"
license=('GPL-3.0-or-later')
depends=(
  'fuse2'
  'python-block_tracing'
  'python-dropbox'
  'python-platformdirs'
  'python-privy'
  'python-sentry_sdk'
  'python-userspacefs'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz"
        'update-check.patch')
sha256sums=('222c6055ca6aeb220e1d65179b998d6ea54f27cae1a3369632e27f93ad1a80d6'
            'b00af1f372b4f420d4e2cb8bf446e5e654db74aeee32636e008cab537968c755')

prepare() {
  cd $pkgname-$pkgver

  # Redirect to AUR page for update URL
  patch -Np1 -i "$srcdir/update-check.patch"
}

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
}