PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31


pkgname=dds10-thumbnailer-kde-git
_pkgname="${pkgname%-git}"
pkgver='r10.23b2801'
pkgrel=1
pkgdesc='dds10-thumbnailer-kde is a plugin for KDE 6 that creates thumbnail for Direct Draw Surface (DDS) images'
arch=('x86_64')
license=('GPLv2')
url=https://github.com/meyraud705/dds10-thumbnailer-kde
makedepends=('cmake' 'extra-cmake-modules')
depends=('qt6-base' 'kio')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${pkgname%-git}::git+https://github.com/meyraud705/dds10-thumbnailer-kde.git")
sha256sums=('SKIP')


build() {
	cmake -B build -S "${pkgname%-git}" -DKDE_INSTALL_USE_QT_SYS_PATHS=ON -DBUILD_WITH_QT6=ON -DCMAKE_BUILD_TYPE=Release
	cmake --build build
}

pkgver() {
	cd "$_pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

package(){
	install -D -m644 -t "$pkgdir/usr/share/licenses/${pkgname%-git}" "${pkgname%-git}/LICENSE"
	DESTDIR="$pkgdir" cmake --install build
}