blob: 0886680560bff0655aa4930c945763fff5770de4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Christopher Snowhill <kode54@gmail.com>
pkgname=deadbeef-plugins-kode54-git
pkgver=r93.f623d26
pkgrel=1
pkgdesc="A set of plugins for DeaDBeeF (Git version)"
url="https://bitbucket.org/losnoco/deadbeef_plugins"
arch=('x86_64')
license=('GPL2'
'LGPL2.1'
'ZLIB'
'proprietary')
makedepends=('cmake' 'git')
depends=('deadbeef' 'zlib' 'libbass' 'libbassmidi' 'libbass_mpc' 'libbassflac' 'libbassopus'
'libbasswv' 'libopenmpt' 'vgmstream-git' 'libmgba')
source=('git+https://bitbucket.org/losnoco/deadbeef_plugins.git'
'libvgm.patch')
md5sums=('SKIP'
'84386467667f5daf4e91c6491c6fa113')
prepare() {
cd "$srcdir/deadbeef_plugins"
# skip osx/deps and external/apbuild submodules
git -c submodule."plugins/vgm/vgmstream".update=none -c submodule."plugins/xsf/mGBA".update=none submodule update --init --recursive
cd "$srcdir/deadbeef_plugins/plugins/libvgm/libvgm"
patch -Np1 -i "$srcdir/libvgm.patch"
}
build() {
cd "$srcdir/deadbeef_plugins/plugins"
env CMAKE_POLICY_VERSION_MINIMUM=3.5 make
}
package() {
cd "$srcdir/deadbeef_plugins/plugins"
make DESTDIR="$pkgdir" install
install -Dm644 libvgm/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.libvgm"
install -Dm644 midi/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.midi"
install -Dm644 openmpt/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.openmpt"
install -Dm644 vfs_fex/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.vfs_fex"
install -Dm644 vgm/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.vgm"
install -Dm644 xsf/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING.xsf"
}
pkgver() {
cd "$srcdir/deadbeef_plugins"
echo r$(git rev-list --count master).$(git rev-parse --short master)
}
|