PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: justforlxz <justforlxz@gmail.com>

pkgname=deepin-control-center-git
_pkgname=deepin-control-center
sourcename=dde-control-center
pkgver=6.0.76.2.r43.gfe51971ef
pkgrel=1
pkgdesc='New control center for linux deepin'
arch=('x86_64' 'aarch64')
url="https://github.com/linuxdeepin/dde-control-center"
license=('GPL3')
depends=(
    'deepin-account-faces'
    'libpwquality'
    'startdde'
    'deepin-daemon'
    'deepin-qt-dbus-factory'
    'deepin-pw-check'
    'qt6-wayland'
    'dtk6core'
    'dtk6widget'
    'dtk6gui'
)
makedepends=(
    'git'
    'cmake'
    'ninja'
    'qt6-tools'
    'qt6-base'
    'qt6-multimedia'
    'qt6-svg'
    'dtkcommon'
    'gtest'
    'gmock'
)
optdepends=('redshift: automatic color temperature support'
            'networkmanager-openconnect: for OpenConnect support'
            'networkmanager-openvpn: for OpenVPN support'
            'networkmanager-pptp: for PPTP support'
            'networkmanager-strongswan: for StrongSwan support'
            'networkmanager-vpnc: for VPNC support'
            'network-manager-sstp: for SSTP support'
            'deepin-network-core'
)
# Not packaged: network-manager-l2tp
conflicts=('deepin-control-center')
provides=('deepin-control-center')
groups=('deepin-git')
source=("git+https://github.com/linuxdeepin/dde-control-center/")
sha512sums=('SKIP')

pkgver() {
    cd $sourcename
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $sourcename
  cmake -B build -GNinja -DDISABLE_SYS_UPDATE=YES \
                -DDISABLE_RECOVERY=YES \
                -DDISABLE_ACTIVATOR=YES \
                -DCMAKE_INSTALL_PREFIX=/usr \
                -DCMAKE_INSTALL_LIBDIR=lib \
                -DDISABLE_AUTHENTICATION=ON \
                -DBUILD_DCC_OLD=OFF
  cmake --build build
}

package() {
  cd $sourcename/build
  DESTDIR="$pkgdir" ninja install
}