PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Erik Bročko (OM2LT) <erik@brocko.eu>

pkgname=digiham-git
pkgver=0.6.2.r11.g410853c
pkgrel=1
pkgdesc="Tools for decoding digital ham communication."
arch=('x86_64')
url="https://github.com/jketterl/digiham"
license=('GPL3')
depends=('mbelib' 'icu' 'codecserver' 'libsamplerate' 'csdr' 'protobuf')
makedepends=('git' 'cmake' 'patch')
conflicts=('digiham')
provides=('digiham')
source=(
	"$pkgname"::'git+https://github.com/jketterl/digiham'
	'change_cppversion.patch'
)
sha256sums=(
	'SKIP'
	'b73615573788c0f2506093bcc050f3b6ff6dde03f7627441003941f2ef45ea67'
)

pkgver() {
	cd "$srcdir/$pkgname"
	# use git tag or fall back to number of revisions
	( set -o pipefail
		git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

prepare() {
    cd "$srcdir/$pkgname"
    patch -p1 < "$srcdir/change_cppversion.patch"
}

build() {
	cmake -B build -S "$srcdir/$pkgname" \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-Wno-dev

	make -C build
}

package() {
	make -C build DESTDIR="$pkgdir/" install
}